Chart Style Unifier

pip install python-docx pywin32

pip install -i https://mirrors.aliyun.com/pypi/simple python-docx pywin32

# 1) Initialize a run directory for table processing
python scripts/init_run.py --table

# 2) Edit the generated config:

# outputs/runs/<timestamp>/config.json

# 3) Execute the table font unification
python scripts/change_table_font.py

{
  "target_doc_path": "C:/Users/xxx/Desktop/document.docx",
  "font_name": "SimSun",
  "font_size": 10,
  "target_type": "table",
  "italic_numbers": false,
  "italic_chinese": false,
  "lowercase_letters": false,
  "status": "pending"
}

Option Explicit

Public Sub NormalizeChartTypography()
    Dim fontName As String
    Dim baseSize As Single, titleSize As Single
    Dim axisTitleSize As Single, tickLabelSize As Single
    Dim legendSize As Single, dataLabelSize As Single

    fontName = InputBox("Font Name", "Unify Chart Fonts", "Times New Roman")
    baseSize = CSng(InputBox("Base Size (ChartArea)", "Unify Chart Fonts", "9"))
    titleSize = CSng(InputBox("Chart Title Size", "Unify Chart Fonts", "11"))
    axisTitleSize = CSng(InputBox("Axis Title Size", "Unify Chart Fonts", "9"))
    tickLabelSize = CSng(InputBox("Tick Label Size", "Unify Chart Fonts", "8"))
    legendSize = CSng(InputBox("Legend Size", "Unify Chart Fonts", "10"))
    dataLabelSize = CSng(InputBox("Data Label Size", "Unify Chart Fonts", "8"))

    Application.ScreenUpdating = False

    Dim ish As InlineShape, shp As Shape
    For Each ish In ActiveDocument.InlineShapes
        If ish.HasChart Then
            ApplyChartTypography ish.Chart, fontName, baseSize, titleSize, axisTitleSize, tickLabelSize, legendSize, dataLabelSize
        End If
    Next ish

    For Each shp In ActiveDocument.Shapes
        If shp.HasChart Then
            ApplyChartTypography shp.Chart, fontName, baseSize, titleSize, axisTitleSize, tickLabelSize, legendSize, dataLabelSize
        End If
    Next shp

    Application.ScreenUpdating = True
End Sub

Private Sub ApplyChartTypography(cht As Object, fontName As String, baseSize As Single, _
                                 titleSize As Single, axisTitleSize As Single, tickLabelSize As Single, _
                                 legendSize As Single, dataLabelSize As Single)
    On Error Resume Next

    With cht.ChartArea.Format.TextFrame2.TextRange.Font
        .Name = fontName
        .Size = baseSize
    End With

    If cht.HasTitle Then
        With cht.ChartTitle.Format.TextFrame2.TextRange.Font
            .Name = fontName
            .Size = titleSize
        End With
    End If

    If cht.HasLegend Then
        With cht.Legend.Format.TextFrame2.TextRange.Font
            .Name = fontName
            .Size = legendSize
        End With
    End If

    Dim axType As Variant, axGroup As Variant, ax As Object
    For Each axType In Array(1, 2) ' 1=xlCategory, 2=xlValue
        For Each axGroup In Array(1, 2) ' 1=xlPrimary, 2=xlSecondary
            Set ax = Nothing
            Set ax = cht.Axes(axType, axGroup)
            If Not ax Is Nothing Then
                ax.TickLabels.Font.Name = fontName
                ax.TickLabels.Font.Size = tickLabelSize
                If ax.HasTitle Then
                    ax.AxisTitle.Format.TextFrame2.TextRange.Font.Name = fontName
                    ax.AxisTitle.Format.TextFrame2.TextRange.Font.Size = axisTitleSize
                End If
            End If
        Next axGroup
    Next axType

    Dim s As Object
    For Each s In cht.SeriesCollection
        If s.HasDataLabels Then
            s.DataLabels.Font.Name = fontName
            s.DataLabels.Font.Size = dataLabelSize
        End If
    Next s

    On Error GoTo 0
End Sub

Option Explicit

Public Sub NormalizeLinkedChartTypography()
    Dim fontName As String
    Dim baseSize As Single, titleSize As Single
    Dim axisTitleSize As Single, tickLabelSize As Single
    Dim legendSize As Single, dataLabelSize As Single

    fontName = InputBox("Font Name", "Unify Chart Fonts", "Times New Roman")
    baseSize = CSng(InputBox("Base Size (ChartArea)", "Unify Chart Fonts", "9"))
    titleSize = CSng(InputBox("Chart Title Size", "Unify Chart Fonts", "11"))
    axisTitleSize = CSng(InputBox("Axis Title Size", "Unify Chart Fonts", "9"))
    tickLabelSize = CSng(InputBox("Tick Label Size", "Unify Chart Fonts", "8"))
    legendSize = CSng(InputBox("Legend Size", "Unify Chart Fonts", "10"))
    dataLabelSize = CSng(InputBox("Data Label Size", "Unify Chart Fonts", "8"))

    Application.ScreenUpdating = False

    Dim ws As Worksheet, co As ChartObject
    For Each ws In ActiveWorkbook.Worksheets
        For Each co In ws.ChartObjects
            ApplyChartTypography co.Chart, fontName, baseSize, titleSize, axisTitleSize, tickLabelSize, legendSize, dataLabelSize
        Next co
    Next ws

    Application.ScreenUpdating = True
End Sub